aboutsummaryrefslogtreecommitdiff
path: root/configure.ac
blob: f162e958590c57dcce6f8f467fd6d304b479f02e (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
dnl Process this file with autoconf to produce a configure script.
AC_PREREQ([2.60])

AC_INIT([iemmatrix], [0.2], [zmoelnig@iem.at], [iemmatrix], [http://puredata.info/downloads/iemmatrix])
AM_INIT_AUTOMAKE([1.10 foreign])
m4_ifdef([LT_INIT], 
	[LT_INIT([disable-static win32-dll])],
	[AC_ENABLE_SHARED
	 AC_DISABLE_STATIC
	 AC_LIBTOOL_WIN32_DLL])

AC_CONFIG_MACRO_DIR([m4])

AC_CONFIG_HEADERS([config.h])
AC_CONFIG_FILES([Makefile])
AC_CONFIG_FILES([doc/Makefile abs/Makefile])
AC_CONFIG_FILES([iemmatrix-meta.pd])
AC_CONFIG_FILES([VERSION.txt])

AC_CONFIG_SRCDIR([src/iemmatrix.c])

IEM_OPERATING_SYSTEM
ARCH=$(uname -m)
KERN=$(uname -s)

dnl m4_ifdef([AC_LIB_RPATH], [AC_LIB_RPATH])

dnl Checks for programs.
AC_PROG_CC
AC_PROG_LN_S
AC_LIBTOOL_WIN32_DLL
AC_PROG_LIBTOOL

AC_ARG_WITH([pd],       [  --with-pd=</path/to/pd> where to look for pd-headers and and -libs])
AC_ARG_WITH([extension],[  --with-extension=<ext>  enforce a certain extension for the dynamic library (e.g. dll)])
AC_ARG_ENABLE([library],[  --enable-library        build iemmatrix as multi-object library (default, "yes"), as single-object externals ("no") or as both ("both")])
AM_CONDITIONAL([LIBRARY], [test "x${enable_library}" != "xno"])
AM_CONDITIONAL([SINGLEOBJECTS], [test "x${enable_library}" = "xno" || test "x${enable_library}" = "xboth"])


if test "x${libdir}" = "x\${exec_prefix}/lib"; then
 libdir='${exec_prefix}/lib/pd/extra'
fi


if test "x$with_pd" != "x"; then
 if test -d "${with_pd}"; then
   PDPATH=${with_pd}
 fi
 if test -d "${PDPATH}/src"; then
  AC_MSG_RESULT([adding ${PDPATH}/src to CPPFLAGS])
  CPPFLAGS="-I${PDPATH}/src ${CPPFLAGS}"

  AC_MSG_RESULT([adding ${PDPATH}/src to LDFLAGS])
  LDFLAGS="-L${PDPATH}/src ${LDFLAGS}"
 else
  if test -d "${PDPATH}"; then
   AC_MSG_RESULT([adding ${PDPATH} to CPPFLAGS])
   CPPFLAGS="-I${PDPATH} ${CPPFLAGS}"
  fi
 fi
 if test -d "${PDPATH}/bin"; then
  AC_MSG_RESULT([adding ${PDPATH}/bin to LDFLAGS])
  LDFLAGS="-L${PDPATH}/bin ${LDFLAGS}"
 else
  if test -d "${PDPATH}"; then
   AC_MSG_RESULT([adding ${PDPATH} to LDFLAGS])
   LDFLAGS="-L${PDPATH} ${LDFLAGS}"
  fi
 fi
fi

dnl Checks for libraries.
dnl Replace `main' with a function in -lc:
AC_CHECK_LIB([c], [main])
AC_CHECK_LIB([crtdll], [fclose])

AC_CHECK_LIB([coldname], [lseek])
AC_CHECK_LIB([kernel32], [main])
AC_CHECK_LIB([user32], [main])
AC_CHECK_LIB([gdi32], [main])

dnl Replace `main' with a function in -lm:
AC_CHECK_LIB([m], [main])
dnl for math.h Bessel/Neumann functions
AC_CHECK_LIB([m], [jn])
AS_IF([test "xyes" = "x${ac_cv_lib_m_jn}"],[
   AC_DEFINE(HAVE_MATH_BESSEL,1,[can math compute Bessel functions?])
])
AM_CONDITIONAL(HAVE_MATH_BESSEL, [test "x${ac_cv_lib_m_jn}" = "xyes"])


dnl Replace `main' with a function in -lpthread:
dnl AC_CHECK_LIB([pthread], [main])
dnl Replace `main' with a function in -lstk:
dnl AC_CHECK_LIB([stk], [main], [STK=yes])

tmp_pddll_LIBS=$LIBS
AC_CHECK_LIB([:pd.dll], [nullfn], [have_pddll="yes"], [have_pddll="no"])
LIBS=$tmp_pddll_LIBS

AS_IF([test "x$have_pddll" = "xyes"],[
  EXTRA_LTFLAGS="$EXTRA_LTFLAGS -Xlinker -l:pd.dll"
  ],[
  AC_CHECK_LIB([pd], [nullfn])
])

dnl Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS([io.h math.h memory.h stdio.h stdlib.h string.h unistd.h])

dnl Checks for typedefs, structures, and compiler characteristics.
AC_HEADER_TIME

dnl Checks for library functions.
AC_FUNC_MMAP

IEM_CHECK_FAT(ARCH_FLAG)

IEM_CHECK_CFLAGS([-mms-bitfields])
IEM_CHECK_SIMD

AC_MSG_CHECKING([extension])
if test "x$with_extension" != "x"
then
 EXTENSION=$with_extension
else
 case "$KERN" in
 Darwin)
   EXTENSION=pd_darwin
   ;;
 Linux)
   EXTENSION=pd_linux
   ;;
 IRIX64)
   EXTENSION=pd_irix6
   ;;
 IRIX32)
   EXTENSION=pd_irix5
   ;;
 IRIX64)
   EXTENSION=pd_irix6
   ;;
 *CYGWIN*)
   EXTENSION=dll
   ;;
 *MINGW*)
   EXTENSION=dll
   ;;
 *)
   EXTENSION=pd_linux
   ;;
 esac
fi
AC_MSG_RESULT([$EXTENSION])

have_pd="no"
AC_CHECK_HEADERS([pd/m_pd.h m_pd.h], [have_pd="yes"])
AS_IF([test "x${have_pd}" = "xno"],[
AC_ERROR([m_pd.h is desperately needed!
        install pd and/or use
        "--with-pd=</path/to/pd/>"])
])

AC_ARG_WITH([fftw], AC_HELP_STRING([--without-fftw], [compile without FFTW]))
AS_IF([test "xno" != "x${with_fftw}" ],[
have_fftw="no"
have_fftw3="no"
AC_CHECK_LIB([fftw3],[fftw_execute])
  AS_IF([test "x$ac_cv_lib_fftw3_fftw_execute" != "xyes"],[
      AC_CHECK_LIB([fftw3-3],[fftw_execute])
      ac_cv_lib_fftw3_fftw_execute=$ac_cv_lib_fftw3_3_fftw_execute
  ])
  AS_IF([test "x$ac_cv_lib_fftw3_fftw_execute" = "xyes"],[
      AC_CHECK_HEADERS([fftw3.h], [have_fftw3="yes"])
  ])
])
AS_IF([test "xyes" = "x${have_fftw3}"],[
   have_fftw="yes"
   AC_DEFINE(HAVE_LIBFFTW3, 1, [Define to 1 if you have the `fftw3' library (-lfftw3).])
])
AS_IF([test "xyes" = "x${have_fftw}"],[
dnl   AC_DEFINE(HAVE_LIBFFTW,1,[Define to 1 if you have the `fftw' library (e.g. -lfftw3).])
   AC_DEFINE(USE_FFTW, 1, [can we use fftw?])
])

AM_CONDITIONAL(HAVE_FFTW, [test "x${have_fftw}" = "xyes"])

dnl for soundfile reading (and writing, if we do that...)
AC_ARG_WITH([sndfile], AC_HELP_STRING([--without-sndfile], [compile without libsndfile support]))
have_sndfile="no"
AS_IF([test "xno" != "x${with_sndfile}"],[
   AC_CHECK_LIB([sndfile], [sf_close])
   AS_IF([test "x$ac_cv_lib_sndfile_sf_close" != "xyes"],[
      AC_CHECK_LIB([sndfile-1],[sf_close])
      ac_cv_lib_sndfile_sf_close=$ac_cv_lib_sndfile_1_sf_close
   ])
   AS_IF([test "x$ac_cv_lib_sndfile_sf_close" = "xyes"],[
       AC_CHECK_HEADERS([sndfile.h], [have_sndfile="yes"])
   ])
])
AS_IF([test "xyes" = "x${have_sndfile}"],[
   AC_DEFINE([HAVE_LIBSNDFILE],1,[Define to 1 if you have the `sndfile' library (-lsndfile).])
   AC_DEFINE([HAVE_SNDFILE_H],1,[Define to 1 if you have the <sndfile.h> header file.])
])
AM_CONDITIONAL(HAVE_SNDFILE, [test "xyes" = "x${have_sndfile}"])


dnl for gnu scientific library -lgsl:
AC_ARG_WITH([gsl], AC_HELP_STRING([--without-gsl], [compile without GNU Scientific Library]))
AS_IF([test "xno" != "x${with_gsl}"],[
   AC_CHECK_LIB([gslcblas], [cblas_dgemm])
   AC_CHECK_LIB([gsl], [gsl_blas_dgemm])
   AS_IF([test "x${ac_cv_lib_gsl_gsl_blas_dgemm}" = "xyes"],[
        AC_CHECK_LIB([gsl], [gsl_eigen_nonsymm], [:])
        AC_CHECK_LIB([gsl], [gsl_sf_bessel_Jn], [:])
   ])
])
AM_CONDITIONAL(HAVE_GSL, [test "x${ac_cv_lib_gsl_gsl_blas_dgemm}" = "xyes"])
AM_CONDITIONAL(HAVE_GSL_CBLAS, [test "x${ac_cv_lib_gslcblas_cblas_dgemm}" = "xyes"])
AS_IF([test "x${ac_cv_lib_gsl_gsl_blas_dgemm}" = "xyes"],[
   AC_DEFINE(HAVE_LIBGSL,1,[Define to 1 if you have the `gsl' library (-lgsl).])
])
AS_IF([test "x${ac_cv_lib_gslcblas_cblas_dgemm}" = "xyes"],[
   AC_DEFINE(HAVE_LIBGSLCBLAS,1,[Define to 1 if you have the `gslcblas' library (-lgslcblas).])
])
AS_IF([test "x${ac_cv_lib_gsl_gsl_eigen_nonsymm}" = "xyes"],[
   AC_DEFINE(HAVE_GSL_EIGEN_NONSYMM,1,[can gsl compute complex eigenvalues?])
])
AM_CONDITIONAL(HAVE_GSL_EIGEN, [test "x${ac_cv_lib_gsl_gsl_eigen_nonsymm}" = "xyes"])

AS_IF([test "x${ac_cv_lib_gsl_gsl_sf_bessel_Jn}" = "xyes"],[
   AC_DEFINE(HAVE_GSL_BESSEL,1,[can gsl compute Bessel functions?])
])
AM_CONDITIONAL(HAVE_GSL_BESSEL, [test "x${ac_cv_lib_gsl_sf_bessel_Jn}" = "xyes"])


AC_SUBST([CPPFLAGS])
AC_SUBST([CFLAGS])
AC_SUBST([LIBS])
AC_SUBST([DEFS])
AC_SUBST([ARCH_FLAG])
AC_SUBST([LIBTOOL_DEPS])
AC_SUBST([EXTRA_LTFLAGS])
AC_SUBST(EXTENSION)

AC_OUTPUT()